Main > Software Forum

two versions of MAME under MAMEWAH

<< < (4/4)

wj2k3:
Is there a list available that shows what is the "best" version of mame to run for each (or atleast most) games?

mccoy178:

--- Quote from: brophog on August 11, 2006, 10:58:43 pm ---Anyone know if beta 9 allows this as well, I'm 100 miles from my arcade to check. I know minwah made some small changes between the two, but I don't know if this was one of them.

--- End quote ---

Yes it does.

brophog:

--- Quote from: wj2k3 on August 18, 2006, 01:54:46 am ---Is there a list available that shows what is the "best" version of mame to run for each (or atleast most) games?

--- End quote ---

No and even if there was, would you ever be able to use it to it's full potential? Probably not, considering the enormity of the situation.

However, there is a resource that let's you quickly find out problems and WIP notes on each rom. It lets you know the status of each driver and a list of changes for each rom.

http://www.mameworld.net/maws

jelwell:
I have 2 versions of MAME, 1 version of Zinc and Daphne all in the same list. I just point mamewah at mame.bat which looks like this:


--- Quote ---rem This batch file tries to add multiple emulator support for a single MAMEWAH list.
rem Currently I use it to do the following:
rem I use MAME .70 for some games that run too slow on modern MAME versions like .95
rem I also use a newer version of MAME to run the cruisn games which were fixed
rem     at some point.
rem And since Zinc uses the same roms as MAME I use Zinc to launch games like Tekken3.
rem     although MAME actually has better support for Strider2 and runs it just fine
rem         so I hand pick which ones to run.
rem I also added Daphne support

rem this is what my commandline from mamewah.log looked like
rem c:\progra~1\ekmame\ek-mame.exe MK2 -mouse -skip_validitychecks -skip_warnings -skip_startup_frames 999 {flags=9}
rem So I just mimic that here

rem Delete "/I" if you are not on an NT based system
rem /I is for Case insensitive matching.
@IF /I "%1" == "crusnusa" GOTO mame95
@IF /I "%1" == "crusnexo" GOTO mame95
@IF /I "%1" == "crusnwld" GOTO mame95

rem Daphne games
@IF /I "%1" == "dlair" GOTO daphne
@IF /I "%1" == "ace" GOTO daphne
@IF /I "%1" == "badlands" GOTO daphne
@IF /I "%1" == "mach3" GOTO daphne

rem Zinc games
@IF /I "%1" == "TEKKEN3" GOTO tekken3
@IF /I "%1" == "SFEX" GOTO sfex

rem Default case below
rem This should point to your main MAME version
cd c:\progra~1\ekmame\
c:\progra~1\ekmame\ek-mame.exe %1 -mouse -skip_validitychecks -skip_warnings -skip_startup_frames 999
GOTO END



rem exceptions below
rem This one should be your secondary MAME version
rem Note that you may not want to pass the same command flags to mame that I do.

:mame95
cd c:\progra~1\Ek-Mame99\
c:\progra~1\Ek-Mame99\ek-mame.exe %1 -mouse -skip_validitychecks -skip_warnings
GOTO END

:daphne
cd e:\daphne\daphne.exe
e:\daphne\daphne.exe %1 vldp -framefile "e:\daphne\mpeg2\%1.txt" -fullscreen
GOTO END

:tekken3
cd c:\progra~1\zinc\
c:\progra~1\zinc\zinc.exe 61 --use-config-file="C:\Program Files\zinc\zinc.cfg" --use-renderer-cfg-file="C:\Program Files\zinc\renderer.cfg"
GOTO END

:sfex
cd c:\progra~1\zinc\
c:\progra~1\zinc\zinc.exe 12 --use-config-file="C:\Program Files\zinc\zinc.cfg" --use-renderer-cfg-file="C:\Program Files\zinc\renderer.cfg"
GOTO END

rem finish up
:END
exit

--- End quote ---

This will work on older versions of MAMEWAH.
Joseph Elwell.

ChicagoDave:
 :applaud:

Joseph, that's  a simple, yet great, idea!

Navigation

[0] Message Index

[*] Previous page

Go to full version